Address Details

contract

// SPDX-License-Identifier: UNLICENSED

pragma solidity 0.8.17.0;

import "../node_modules/@openzeppelin/contracts/access/Ownable.sol";
import "../node_modules/@openzeppelin/contracts/security/Pausable.sol";
import "../node_modules/@openzeppelin/contracts/utils/math/Math.sol";
import "../node_modules/@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "./DataStructure.sol";
import "./IUnergyData.sol";

abstract contract PermissionGranterAbs {

    function getPermission(
        address addressReq,
        address contractAddress,
        string memory fname
    ) public virtual returns(bool);

}

abstract contract ERC20Abs {
    function mint(
        address account,
        uint256 amount
    ) public virtual;
    function burn(
        address account,
        uint256 amount
    ) public virtual;
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual;
    function transfer(
        address to,
        uint256 amount
    ) public virtual;
    function burnFrom(
        address owner,
        uint256 amount
    ) public virtual;
    function balanceOf(
        address account
    ) public virtual returns(uint256);
    function approveSwap(
        address owner,
        address spender,
        uint256 amount
    ) public virtual;
    function allowance (
        address owner,
        address spender
    ) public virtual returns(uint256);
    function decimals()
    public virtual returns(uint256);
}

abstract contract ERC1155Abs {
    function mint(
        address projectAddr,
        uint256 amount
    ) public virtual;
    function burn(
        address projectAddr,
        uint256 amount
    ) public virtual;
}

contract UnergyLogicOperation is ReentrancyGuard, Pausable, Ownable {

    ///@dev Variables
    
    IUnergyData public unergyData;
    address public unergyDataAddr;
    address public unergyLogicFundingAddr;
    address public cleanEnergyAssetsAddr;
    address public permissionGranterAddress;
    address public maintenanceAddress;
    address payable public recipient;

    ///@dev Events

    event ProjectCreated(DataStructure.Project project);
    event EnergyReport(
        address projectAddr,
        uint256 currentAccEnergy,
        uint256 deltaEnergy
    );
    event InvoiceReport(
        address projectAddr,
        uint256 energyDelta,
        uint256 energyTariff,
        uint256 income,
        uint256 eventDepreciation
    );

    ///@dev Contract Functions.

    constructor(
        address _unergyDataAddr,
        address _maintenanceAddr,
        address payable owner_
    ) 
    {
        unergyDataAddr = _unergyDataAddr;
        unergyData = IUnergyData(unergyDataAddr);
        maintenanceAddress = _maintenanceAddr;//does this goes here?
        recipient = owner_;
        
    }

    ///@dev Modifiers.

    modifier hasRoleInPermissionGranter(
        address _address,
        string memory _fname
    )
    {
        PermissionGranterAbs permissionGranter =
        PermissionGranterAbs(permissionGranterAddress);
        bool permissionState = 
        permissionGranter.getPermission(
            _address,
            address(this),
            _fname  
        );
        require(permissionState == true);
        _;
    }

    function setProjectSignature(
        address _projectAddr,
        uint256 _signatureProfile
    )
        public
        whenNotPaused
        hasRoleInPermissionGranter(
            msg.sender,
            "setProjectSignature"
        )
    {
        unergyData.setSignature(
            _projectAddr,
            _signatureProfile
        );
    }

    function energyReport(
        address _projectAddr,
        uint256 _currentAccEnergy
    )
        public
        whenNotPaused
        hasRoleInPermissionGranter(
            msg.sender,
            "energyReport"
        )
    {
        ERC1155Abs cleanEnergyAssets =
        ERC1155Abs(cleanEnergyAssetsAddr);
        uint256 lastAccEnergy = 
        unergyData.getAccEnergyByMeter(
            _projectAddr, 
            msg.sender
        );
        require( 
            lastAccEnergy < _currentAccEnergy,
            "Accumulated energy must be greater than the registered energy"
        );
        uint256 energyDelta = (
            _currentAccEnergy- lastAccEnergy
        );
        if (unergyData.getAccEnergyByMeter(
                    _projectAddr,
                    msg.sender
                ) == 0
            )
            {
            unergyData.setAccEnergyByMeter(
                _projectAddr,
                msg.sender,
                _currentAccEnergy
            );
        } else {
            unergyData.setAccEnergyByMeter(
                _projectAddr,
                msg.sender,
                _currentAccEnergy
            );
            cleanEnergyAssets.mint(
                _projectAddr,
                energyDelta
            );
        }
        emit EnergyReport(
            _projectAddr,
            _currentAccEnergy,
            energyDelta
        );
    }

    function externalInvoiceReport(
        address _projectAddr,
        address _stableCoindAddr,
        uint256 _amount,
        uint256 _energyDelta,
        uint256 _energyTariff,
        uint256 _depreciationPercentage
    )
        public
        whenNotPaused
        hasRoleInPermissionGranter(
            msg.sender,
            "externalInvoiceReport"
        )
    {
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        uint256 maintenanceIncome =
        Math.mulDiv(
            _amount,
            project.maintenancePercentage,
            10000
        );
        uint256 profitIncome = _amount - maintenanceIncome;
        ERC20Abs stableCoin = ERC20Abs(_stableCoindAddr);
        ///@dev transfer profitIncome funds to this contract
        stableCoin.transferFrom(msg.sender, address(this), profitIncome);
        ///@dev transfer maintenanceIncome funds to maintenance address
        stableCoin.transferFrom(
            msg.sender,
            maintenanceAddress,
            maintenanceIncome
        );
        invoiceReport(
            _projectAddr,
            _amount,
            _energyDelta,
            _energyTariff,
            _depreciationPercentage
        );
    }

    function invoiceReport(
        address _projectAddr,
        uint256 income,
        uint256 _energyDelta,
        uint256 _energyTariff,
        ///@dev Scaled value by 1e6;
        uint256 _depreciationPercentage
    )
        internal
    {
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        DataStructure.DepreciatedBalance memory depreciatedBalance =
        unergyData.getDepreciatedBalance();
        DataStructure.Tokens memory tokens = project.tokens;
        uint256 totalSupply = tokens.pWatts;
        DataStructure.ProjectState state = project.state;
        uint256 eventDepreciation;
        if (state == DataStructure.ProjectState.INSTALLED) {
            eventDepreciation = 0;
        } else if (state == DataStructure.ProjectState.PRODUCTION) {
            ///@dev 1e8 value is scaling compensation
            uint256 pWattDepreciated = Math.mulDiv(
                totalSupply,
                _depreciationPercentage,
                1e8
            );
            depreciatedBalance.pWattDepreciated +=
            pWattDepreciated;
            project.pWattDepreciated += 
            pWattDepreciated;
            ERC20Abs pWatt = ERC20Abs(_projectAddr);
            pWatt.burn(
                address(this),
                pWattDepreciated
            );
            eventDepreciation = project.pWattDepreciated;
        }
        unergyData.updateProject(
            _projectAddr,
            project
        );
        unergyData.setDepreciatedBalance(depreciatedBalance);
        ERC1155Abs cleanEnergyAssets =
        ERC1155Abs(cleanEnergyAssetsAddr);
        cleanEnergyAssets.burn(
            _projectAddr,
            _energyDelta
        );
        emit InvoiceReport(
            _projectAddr,
            _energyDelta,
            _energyTariff,
            income,
            eventDepreciation
        );
    }

    function pWattsTransfer(
        address _projectAddr,
        address _stableCoindAddr,
        address _receiver,
        uint256 _amount,
        uint256 _pWattPrice
    )
        public
        hasRoleInPermissionGranter(
            msg.sender,
            "pWattsTransfer"
        )
        
    {
        ERC20Abs stableCoin = ERC20Abs(_stableCoindAddr);
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        DataStructure.Tokens memory token = project.tokens;
        uint256 decimals = stableCoin.decimals();
        if(unergyData.getItIsInstitutionalAddress(
                _receiver,
                _projectAddr
            )
        ) 
        {
            token.pWatts -= _amount;
            token.eWatts += _amount;
            unergyData.updateProject(_projectAddr, project);
        }
        if(_receiver == unergyLogicFundingAddr) {
            stableCoin.transfer(
                project.adminAddr,
                _amount * _pWattPrice*(10**(decimals - 4))
            );
            _pWattsTransfer(
                _projectAddr,
                _receiver,
                _amount
            );
            
        } else {
            stableCoinTransferFrom(
                _projectAddr,
                _stableCoindAddr,
                msg.sender,
                _receiver,
                _amount,
                _pWattPrice
            );
        }
    }

    function stableCoinTransferFrom(
        address _projectAddr,
        address _stableCoindAddr,
        address sender,
        address _receiver,
        uint256 _amount,
        uint256 _pWattPrice

    ) 
        internal
    {
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        DataStructure.Tokens memory token = project.tokens;
        ERC20Abs pWatt = ERC20Abs(_projectAddr);
        ERC20Abs stableCoin = ERC20Abs(_stableCoindAddr);
        uint256 decimals = stableCoin.decimals();

        stableCoin.transferFrom(
            sender,
            project.adminAddr,
            _amount * _pWattPrice * (10 ** (decimals - 4))
        ); 
        pWatt.transferFrom(
            project.adminAddr,
            _receiver,
            _amount
        );
        pWatt.approveSwap(
            _receiver,
            address(this),
            token.pWatts
        );

    }

     function _pWattsTransfer(
        address _projectAddr,
        address _receiver,
        uint256 _amount
        
    ) 
        internal
    {
        ERC20Abs pWatt = ERC20Abs(_projectAddr);
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        DataStructure.Tokens memory token =
        project.tokens;

        pWatt.transferFrom(
            project.adminAddr,
            _receiver,
            _amount
        );
        pWatt.approveSwap(
            _receiver,
            address(this),
            token.pWatts
        );
    }

    function swapToken(address _projectAddr) 
        public
        hasRoleInPermissionGranter(
            msg.sender,
            "swapToken"
        )
    {
        ERC20Abs pWatt = ERC20Abs(_projectAddr);
        DataStructure.Holders[] memory holders;
        holders = 
        unergyData.getHolders(_projectAddr);
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        DataStructure.HistoricalSwap memory historicalSwap;
        uint256 unergyUWatts;
        uint256 depreciatedPwatts;
        for (uint256 i; i < holders.length; i++) {
            bool isInstitutional =
            unergyData.getItIsInstitutionalAddress(
                holders[i].addr,
                _projectAddr
            );
            uint256 pWattsPerHolder = 
            pWatt.balanceOf(holders[i].addr);
            if(holders[i].addr == unergyLogicFundingAddr){
                pWatt.transferFrom(
                    holders[i].addr,
                    address(this),
                    pWattsPerHolder
                );
                DataStructure.DepreciatedBalance memory depreciatedBalance =
                unergyData.getDepreciatedBalance();
                ///@dev If pWatt balance depreciation is less than 
                // pWatt balance on a particular project then all pWatts
                // for reserve will be for compensation of depreciation  
                if (depreciatedBalance.pWattDepreciated < pWattsPerHolder){
                    ///@dev Generate uWatts
                    unergyUWatts = 
                    Math.mulDiv(
                        (pWattsPerHolder - depreciatedBalance.pWattDepreciated),
                        project.swapFactor,
                        100
                    );
                    uWattsTransfer(holders[i].addr, unergyUWatts);
                    ///@dev All Depreciated pWatts are compensated
                    depreciatedPwatts = depreciatedBalance.pWattDepreciated;
                    depreciatedBalance.pWattDepreciated -= depreciatedPwatts;
                }
                else {
                    ///@dev No uWatts generated
                    unergyUWatts = 0;
                    ///@dev Depreciation is equal to pWatts
                    depreciatedPwatts = pWattsPerHolder;
                    depreciatedBalance.pWattDepreciated -=
                    depreciatedPwatts;
                }
                unergyData.setDepreciatedBalance(depreciatedBalance);
            } else {
                if(pWattsPerHolder != 0 && !isInstitutional){
                    pWatt.transferFrom(
                        holders[i].addr,
                        address(this),
                        pWattsPerHolder
                    );
                    uWattsTransfer(
                        holders[i].addr,
                        Math.mulDiv(
                            pWattsPerHolder,
                            project.swapFactor,
                            100
                        )
                    );
                }
            }
        }
        historicalSwap.uWattsUnergy = unergyUWatts;
        historicalSwap.totalUWatts = 
        unergyData.getTotalPWatts(_projectAddr) - depreciatedPwatts;
        historicalSwap.totalSupplyAccumulated +=  
        historicalSwap.totalUWatts;
        unergyData.setHistoricalSwaps(historicalSwap);
    }

    function customSwap(
        address _projectAddr
    ) 
        public
        nonReentrant
    {
        ERC20Abs pWatt = ERC20Abs(_projectAddr);
        DataStructure.Project memory project =
        unergyData.getProject(_projectAddr);
        uint256 amount = pWatt.balanceOf(msg.sender);
        DataStructure.Tokens memory token = project.tokens;
        DataStructure.DepreciatedBalance memory depreciatedBalance =
        unergyData.getDepreciatedBalance();
        ///@dev Burn calculate and burn tokens
        uint256 depreciatedPwatts = project.pWattDepreciated;
        uint256 totalPwatts = token.pWatts;
        uint256 percentageToDepreciate =
        Math.mulDiv(
            depreciatedPwatts,
            100000,
            totalPwatts
        );
        uint256 pWattsToBurn =
        Math.mulDiv(
            amount,
            percentageToDepreciate,
            100000
        );
        pWatt.burnFrom(msg.sender, pWattsToBurn);
        ///@dev convert eWatts for pWatts if msg sender is institutional
        if(unergyData.getItIsInstitutionalAddress(
                msg.sender,
                _projectAddr
            )
        )
        {
            token.pWatts += amount;
            token.eWatts -= amount;
            unergyData.updateProject(_projectAddr, project);
        }
        
        ///@dev pWatts transferFrom
        uint256 pWattsAfterBurn = pWatt.balanceOf(msg.sender);
        pWatt.transferFrom(
            msg.sender,
            address(this),
            pWattsAfterBurn
        ); 
        ///@dev uWatts transfer
        uWattsTransfer(
            msg.sender,
            Math.mulDiv(
                pWattsAfterBurn,
                project.swapFactor,
                100
            )
        );
    }

    function uWattsTransfer(
        address _receiver,
        uint256 _amount
    ) 
        internal virtual
    {
        address uWattAddress = 
        unergyData.getUWattAddress();
        ERC20Abs uWatt = ERC20Abs(uWattAddress);
        uWatt.mint(_receiver, _amount);
    }

    function updateLastUWattStatus (
        address _sender,
        address _receiver,
        uint256 _amount
    )
        public
        whenNotPaused
        hasRoleInPermissionGranter(
            msg.sender,
            "updateLastUWattStatus"
        )
    {
        DataStructure.UWattStatus[] memory senderUWattStatusList = 
        unergyData.getHolderUWattStatus(_sender);
        DataStructure.UWattStatus[] memory receiverUWattStatusList = 
        unergyData.getHolderUWattStatus(_receiver);
        bool isFunding;
        if(_sender == unergyLogicFundingAddr){
            isFunding = true;
        }else{
            isFunding = false;
        }
        uint256 claimNumber =
        unergyData.getHistoricalSwapLength();
        if (_sender != address(0)) {
            DataStructure.UWattStatus memory lastSenderUWattStatus;
            if(senderUWattStatusList.length == 0){
                lastSenderUWattStatus.uWattsSold = _amount;
                lastSenderUWattStatus.totalUWatts = _amount;
                lastSenderUWattStatus.claimStatus = true;
                lastSenderUWattStatus.claimNumber = claimNumber;
                unergyData.setHolderUWattStatus(
                    _sender,
                    lastSenderUWattStatus
                );
            } else {
                lastSenderUWattStatus = 
                senderUWattStatusList[senderUWattStatusList.length -1];
                lastSenderUWattStatus.uWattsSold += _amount;
                lastSenderUWattStatus.totalUWatts += _amount;
                unergyData.updateHolderUWattStatus(
                    _sender,
                    lastSenderUWattStatus
                );
            }
        }
        if(_receiver != address(0)) {
            DataStructure.UWattStatus memory lastReceiverUWattStatus;
            if(receiverUWattStatusList.length == 0){
                lastReceiverUWattStatus.uWattsPurchased = _amount;
                lastReceiverUWattStatus.totalUWatts = _amount;
                lastReceiverUWattStatus.claimStatus = true;
                lastReceiverUWattStatus.claimNumber = claimNumber;
                unergyData.setHolderUWattStatus(
                    _receiver,
                    lastReceiverUWattStatus
                );
            } else {
                lastReceiverUWattStatus = 
                receiverUWattStatusList[receiverUWattStatusList.length - 1];
                if(!isFunding){
                    lastReceiverUWattStatus.uWattsPurchased += _amount;
                    lastReceiverUWattStatus.totalUWatts += _amount;
                    unergyData.updateHolderUWattStatus(
                        _receiver,
                        lastReceiverUWattStatus
                    );
    
                } else {
                    unergyData.updateHolderUWattStatus(
                        _receiver,
                        lastReceiverUWattStatus
                    );
                    unergyData.setNextHolderUWattStatus(
                        _receiver,
                        lastReceiverUWattStatus
                    );
                }    
            }
        }
    }

    function claimUWatts(
        address _user,
        DataStructure.UWattStatus memory actualClaim,
        DataStructure.UWattStatus memory previousClaim
    ) 
        internal
        whenNotPaused
    {
        DataStructure.HistoricalSwap[] memory historicalSwaps = 
        unergyData.getHistoricalSwap();
        actualClaim.uWattsCurrentClaim = 
        historicalSwaps[actualClaim.claimNumber].uWattsUnergy;
        uint256 totalSupplyAcc = 
        historicalSwaps[previousClaim.claimNumber].totalSupplyAccumulated;
        actualClaim.percentageToClaim =
        Math.mulDiv(
            actualClaim.currentUWatts,
            10000000000,
            totalSupplyAcc
        );
        actualClaim.uWattsClaimed = 
            Math.mulDiv(
                actualClaim.uWattsCurrentClaim,
                actualClaim.percentageToClaim,
                10000000000
            );
        actualClaim.claimStatus = true;
        actualClaim.totalUWatts =
        actualClaim.currentUWatts +
        actualClaim.uWattsPurchased +
        actualClaim.uWattsClaimed -
        actualClaim.uWattsSold;
        unergyData.updateHolderUWattStatus(_user, actualClaim);
        ///@dev transfer uWatts claimed
        address uWattAddress =
        unergyData.getUWattAddress();
        ERC20Abs uWatt = 
        ERC20Abs(uWattAddress);
        uWatt.transferFrom(
            unergyLogicFundingAddr,
            _user, actualClaim.uWattsClaimed
        );
    }

    function iterativeClaim()  public whenNotPaused {
        DataStructure.UWattStatus[] memory userUWattStatusList = 
        unergyData.getHolderUWattStatus(msg.sender);
        uint256 historicalSwapLength =
        unergyData.getHistoricalSwapLength();
        uint256 firstClaimNumber =
        userUWattStatusList[0].claimNumber;
        uint256 lastClaimNumber;
        for (uint256 i; i < historicalSwapLength; i++) {
            if(userUWattStatusList[i].claimStatus == false) {
                lastClaimNumber =
                userUWattStatusList[i].claimNumber;
                break;
            }
        }
        if(firstClaimNumber == 0){
            for (uint256 i = lastClaimNumber; i < historicalSwapLength; i++) {
                claimUWatts(
                    msg.sender,
                    userUWattStatusList[i],
                    userUWattStatusList[i - 1]
                );
                userUWattStatusList =
                unergyData.getHolderUWattStatus(msg.sender);
            }
        } else {
            for(
                    uint256 i = lastClaimNumber - firstClaimNumber;
                    i < historicalSwapLength - firstClaimNumber;
                    i++
                ) 
            {
                claimUWatts(
                    msg.sender,
                    userUWattStatusList[i],
                    userUWattStatusList[i - 1]
                );
                userUWattStatusList =
                unergyData.getHolderUWattStatus(msg.sender);
            }
        }
    }

    ///@dev set UnergyLogicFunding contract address
    function setUnergyLogicFundingAddr(address _address)
        public
        whenNotPaused
        onlyOwner 
    {
        unergyLogicFundingAddr = _address;
    }

    ///@dev set CleanEnergyAssets contract address
    function setCleanEnergyAssetsAddr(address _address) 
        public
        whenNotPaused
        onlyOwner 
    {
        cleanEnergyAssetsAddr = _address;
    }

    function setPermissionGranterAddr(address _addr)
        public
        whenNotPaused
        onlyOwner
    {
        permissionGranterAddress = _addr;
    }

    ///@dev Ownable methods overridden
    function transferOwnership(address newOwner)
        public
        whenNotPaused
        override
        onlyOwner 
    {
        require(
            newOwner != address(0),
            "Ownable: new owner cannot be the zero address"
        );
        _transferOwnership(newOwner);
    }

    ///@dev Pausable method
    function pauseContract()
        public
        onlyOwner
        whenNotPaused
    {
        _pause();
    }

    ///@dev Pausable method
    function unPauseContract()
        public
        onlyOwner
        whenNotPaused
    {
        _unpause();
    }

    function closeContract() 
        public
        onlyOwner
    {
        selfdestruct(recipient);
    }

}
        

// SPDX-License-Identifier: UNLICENSED

pragma solidity 0.8.17.0;

library DataStructure {

    enum ProjectState {
        FUNDING,
        INSTALLED,
        PRODUCTION,
        CLOSED,
        CANCELLED
    }

    struct PWattPrice { 
        uint256 initialValue;
        uint256 finalValue;
    }

    struct Tokens {
        uint256 pWatts;
        uint256 eWatts;
    }

    struct Project {
        uint256 idProject;
        uint256 maintenancePercentage;
        PWattPrice pWattPrice;
        uint256 swapFactor;
        ProjectState state;
        address projectAddr;
        address adminAddr;
        address installerAddr;
        uint256 pWattDepreciated;
        Tokens tokens;
    }

    struct Holders {
        address addr;
        bool fiat;
    }

    struct DepreciatedBalance {
        uint256 pWattDepreciated;
    }

    struct Milestone {
        string name;
        bool state;
        uint256 weight;
        bool installerSignature;
        bool unergySignature;
    }

    enum ProjectType {
        pWatt,
        eWatt
    }

    struct HistoricalSwap {
        uint256 id;
        uint256 uWattsUnergy;
        uint256 totalUWatts;
        uint256 totalSupplyAccumulated;
    }

    struct UWattStatus { 
        uint256 currentUWatts;
        uint256 uWattsSold;
        uint256 uWattsPurchased;
        uint256 claimNumber;
        uint256 uWattsCurrentClaim;
        uint256 percentageToClaim;
        uint256 uWattsClaimed;
        uint256 totalUWatts;
        bool claimStatus;
    }

}
          

// SPDX-License-Identifier: UNLICENSED

pragma solidity 0.8.17.0;

import "./DataStructure.sol";

interface IUnergyData {

    ///@dev Set Functions

    function setProject(
        DataStructure.Project memory project
    ) external;
    function setHolders(
        address projectAddr,
        address holder
    ) external;
    function setUWattsAddr(address uWattsAddr) external;
    function setMilestone(
        address projectAddr,
        string memory name,
        uint256 weight
    ) external;
    function setMilestones(
        address projectAddr, 
        DataStructure.Milestone[] memory milestone
    ) external;
    function setSignature(
        address projectAddr,
        uint256 signatureProfile
    ) external;
    function setDepreciatedBalance(
        DataStructure.DepreciatedBalance memory depreciatedBalance
    ) external;
    function setAccEnergyByMeter(
        address projectAddr,
        address meterAddr,
        uint256 accEnergy
    ) external;
    function setHistoricalSwaps(
        DataStructure.HistoricalSwap memory historicalSwap
    ) external;
    function setHolderUWattStatus(
        address holderAddress,
        DataStructure.UWattStatus memory uWattStatus
    ) external;
    function setNextHolderUWattStatus(
        address holderAddress,
        DataStructure.UWattStatus memory uWattStatus
    ) external;
    function updateHolderUWattStatus (
        address holderAddress,
        DataStructure.UWattStatus memory uWattStatus
    ) external;
    function updateProject(
        address projectAddr,
        DataStructure.Project memory project
    ) external;
    function updateMilestones(
        address projectAddr,
        DataStructure.Milestone[] memory milestone,
        uint256 index
    ) external;
    function deleteMilestone(
        address projectAddr,
        uint256 index
    ) external;
    function setInstitutionalAddress(
        address userAddress,
        address projectAddress,
        bool state
    ) external;

    ///@dev Get Functions
    
    function getProject(
        address projectAddr
    ) external returns(DataStructure.Project memory);
    function getDepreciatedBalance() 
    external returns (DataStructure.DepreciatedBalance memory);
    function getUWattAddress() external returns(address);
    function getHistoricalSwap() external
    returns(DataStructure.HistoricalSwap[] memory);
    function getHolderUWattStatus(
        address holderAddress
    ) external returns (DataStructure.UWattStatus[] memory);
    function getTotalPWatts(
        address projectAddr
    ) external returns(uint256);
    function getProjectState(
        address projectAddr
    ) external returns(DataStructure.ProjectState);
    function getHolders(
        address projectAddr
    ) external returns(DataStructure.Holders[] memory);
    function getMilestones(
        address projectAddr
    ) external returns(DataStructure.Milestone[] memory);
    function getSignatures(
        address projectAddr
    )external returns(bool[2] memory);
    function getAccEnergyByMeter(
        address projectAddr,
        address meterAddr
    ) external returns(uint256);
    function getItIsInstitutionalAddress(
        address userAddress,
        address projectAddress
    ) external returns(bool);
    function getHistoricalSwapLength()
    external returns(uint256);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity 0.8.17.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)

pragma solidity 0.8.17.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity 0.8.17.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator
    ) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1);

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator,
        Rounding rounding
    ) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10**64) {
                value /= 10**64;
                result += 64;
            }
            if (value >= 10**32) {
                value /= 10**32;
                result += 32;
            }
            if (value >= 10**16) {
                value /= 10**16;
                result += 16;
            }
            if (value >= 10**8) {
                value /= 10**8;
                result += 8;
            }
            if (value >= 10**4) {
                value /= 10**4;
                result += 4;
            }
            if (value >= 10**2) {
                value /= 10**2;
                result += 2;
            }
            if (value >= 10**1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10**result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result * 8) < value ? 1 : 0);
        }
    }
}