Address Details

contract

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.10;

import "./Wedding.sol";
import "../IController.sol";

contract FactoryWedding is ReentrancyGuard {
    using SafeERC20 for IERC20;

    IController public immutable CONTROLLER;

    mapping (address => uint256) public price;

    event NewContract(address contractAddress, address firstPartner, address secondPartner);

    modifier canSetPrice {
        require(CONTROLLER.canSetPrice(msg.sender), "Cannot set price");
        _;
    }

    constructor(IController _controller) {
        CONTROLLER = _controller;
    }

    function setPrice(address _token, uint256 _price) external canSetPrice {
        price[_token] = _price;
    }

    function deployWedding(
        address tokenToPay,
        address _firstPartner, address _secondPartner,
        uint256 _decisionTimeWithdrawal, uint256 _decisionTimeDivorce,
        uint8 _percentageToProposingWhenDisputed
    ) external nonReentrant {
        uint256 _price = price[tokenToPay];
        require(_price > 0, "Wrong payment method");
        IERC20(tokenToPay).safeTransferFrom(msg.sender, CONTROLLER.feeReceiver(), _price);
        Wedding _wedding = new Wedding(_firstPartner, _secondPartner, _decisionTimeWithdrawal, _decisionTimeDivorce, _percentageToProposingWhenDisputed);
        emit NewContract(address(_wedding), _firstPartner, _secondPartner);
    }
}
        

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.10;

interface IController {

    function feeReceiver() external view returns(address);

    function canSetPrice(address) external view returns(bool);
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.10;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";

contract Wedding is ReentrancyGuard {
    using SafeERC20 for IERC20;

    address public firstPartner;
    address public secondPartner;

    uint256 public decisionTimeWithdrawal;
    uint256 public decisionTimeDivorce;

    uint8 public percentageToProposingWhenDisputed;

    uint256 public divorceTimestamp;
    address public divorceProposedBy;
    bool public divorceDisputed;

    bool public withdrawalProposalPending;
    WithdrawalProposal public activeWithdrawalProposal;

    mapping (IERC20 => bool[2]) public partsTakenAfterDivorce;

    struct WithdrawalProposal {
        IERC20 token;
        address receiver;
        uint256 amount;
        address proposedBy;
        uint256 timestamp;
    }

    event WithdrawalProposed(address token, address receiver, uint256 amount, address proposedBy);
    event DivorceProposed(address proposedBy, uint256 timestamp);
    event WithdrawalStatus(bool agreed, address executedBy);
    event DivorceStatus(bool agreed);

    modifier onlyCouple() {
        require(msg.sender == firstPartner || msg.sender == secondPartner, "Not a couple");
        _;
    }

    modifier divorceNotProposed() {
        require(divorceTimestamp == 0, "Divorce already proposed");
        _;
    }

    modifier divorceProposedAndNotDone() {
        require(divorceTimestamp > 0, "Divorce not proposed");
        require(block.timestamp < divorceTimestamp, "Already divorced");
        _;
    }

    modifier checkAndDelete() {
        require(withdrawalProposalPending, "Already executed or not proposed yet");
        withdrawalProposalPending = false;
        _;
    }

    constructor(address _firstPartner, address _secondPartner, uint256 _decisionTimeWithdrawal, uint256 _decisionTimeDivorce, uint8 _percentageToProposingWhenDisputed) {
        require(_firstPartner != _secondPartner, "Cannot use same address");
        require(_percentageToProposingWhenDisputed <= 100, "Percentage cannot be higher than 100");
        firstPartner = _firstPartner;
        secondPartner = _secondPartner;
        decisionTimeWithdrawal = _decisionTimeWithdrawal;
        decisionTimeDivorce = _decisionTimeDivorce;
        percentageToProposingWhenDisputed = _percentageToProposingWhenDisputed;
    }

    function proposeWithdrawal(address _token, address _receiver, uint256 _amount) external onlyCouple divorceNotProposed {
        require(!withdrawalProposalPending, "Proposal already pending");
        activeWithdrawalProposal.token = IERC20(_token);
        activeWithdrawalProposal.receiver = _receiver;
        activeWithdrawalProposal.amount = _amount;
        activeWithdrawalProposal.proposedBy = msg.sender;
        activeWithdrawalProposal.timestamp = block.timestamp;
        withdrawalProposalPending = true;
        emit WithdrawalProposed(_token, _receiver, _amount, msg.sender);
    }

    function executeWithdrawalProposal() external onlyCouple divorceNotProposed nonReentrant checkAndDelete {
        require(activeWithdrawalProposal.proposedBy != msg.sender || activeWithdrawalProposal.timestamp + decisionTimeWithdrawal < block.timestamp, "Proposal must be done by another partner or decision time must run out");
        activeWithdrawalProposal.token.safeTransfer(activeWithdrawalProposal.receiver, activeWithdrawalProposal.amount);
        delete activeWithdrawalProposal;
        emit WithdrawalStatus(true, msg.sender);
    }

    function rejectWithdrawalProposal() external onlyCouple divorceNotProposed checkAndDelete {
        require(activeWithdrawalProposal.proposedBy != msg.sender, "Proposal must be done by another partner");
        require(activeWithdrawalProposal.timestamp + decisionTimeWithdrawal >= block.timestamp, "Decision time ran out");
        delete activeWithdrawalProposal;
        emit WithdrawalStatus(false, msg.sender);
    }

    function proposeDivorce() external onlyCouple divorceNotProposed {
        divorceTimestamp = block.timestamp + decisionTimeDivorce;
        divorceProposedBy = msg.sender;
        emit DivorceProposed(msg.sender, divorceTimestamp);
    }

    function agreeWithDivorce() external onlyCouple divorceProposedAndNotDone {
        require(divorceProposedBy != msg.sender, "Other partner must agree");
        divorceTimestamp = block.timestamp;
        emit DivorceStatus(true);
    }

    function disputeDivorce() external onlyCouple divorceProposedAndNotDone {
        require(divorceProposedBy != msg.sender, "Other partner must dispute");
        divorceDisputed = true;
        divorceTimestamp = block.timestamp;
        emit DivorceStatus(false);
    }

    function getFundsAfterDivorce(address[] calldata _tokens) external onlyCouple nonReentrant {
        require(divorceTimestamp > 0 && block.timestamp >= divorceTimestamp, "Not divorced");
        uint256 share;
        uint8 ID;
        uint8 mirrorID;
        if (msg.sender == divorceProposedBy) {
            mirrorID = 1;
        }
        else {
            ID = 1;
        }
        if (divorceDisputed) {
            if (ID == 0) {
                share = percentageToProposingWhenDisputed;
            }
            else {
                share = 100 - percentageToProposingWhenDisputed;
            }
        }
        else {
            share = 50;
        }
        for (uint256 i; i < _tokens.length; i++) {
            IERC20 currentToken = IERC20(_tokens[i]);
            if (!partsTakenAfterDivorce[currentToken][ID]) {
                uint256 toTransfer = currentToken.balanceOf(address(this));
                if (!partsTakenAfterDivorce[currentToken][mirrorID]) {
                    toTransfer = (toTransfer * share) / 100;
                }
                if (toTransfer > 0) {
                    try currentToken.transfer(msg.sender, toTransfer) {
                        partsTakenAfterDivorce[currentToken][ID] = true;
                    }
                    catch {}
                }
            }
        }
    }
}